cmake px4_base -> px4_parse_function_args

cmake/px4_parse_function_args.cmake

@@ -0,0 +1,103 @@
+############################################################################
+#
+# Copyright (c) 2015 PX4 Development Team. All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+#
+# 1. Redistributions of source code must retain the above copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+#    notice, this list of conditions and the following disclaimer in
+#    the documentation and/or other materials provided with the
+#    distribution.
+# 3. Neither the name PX4 nor the names of its contributors may be
+#    used to endorse or promote products derived from this software
+#    without specific prior written permission.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+# FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+# COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+# BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
+# OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
+# AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+# LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+# ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+#
+############################################################################
+
+#=============================================================================
+#
+#	px4_parse_function_args
+#
+#	This function simplifies usage of the cmake_parse_arguments module.
+#	It is intended to be called by other functions.
+#
+#	Usage:
+#		px4_parse_function_args(
+#			NAME <name>
+#			[ OPTIONS <list> ]
+#			[ ONE_VALUE <list> ]
+#			[ MULTI_VALUE <list> ]
+#			REQUIRED <list>
+#			ARGN <ARGN>)
+#
+#	Input:
+#		NAME		: the name of the calling function
+#		OPTIONS		: boolean flags
+#		ONE_VALUE	: single value variables
+#		MULTI_VALUE	: multi value variables
+#		REQUIRED	: required arguments
+#		ARGN		: the function input arguments, typically ${ARGN}
+#
+#	Output:
+#		The function arguments corresponding to the following are set:
+#		${OPTIONS}, ${ONE_VALUE}, ${MULTI_VALUE}
+#
+#	Example:
+#		function test()
+#			px4_parse_function_args(
+#				NAME TEST
+#				ONE_VALUE NAME
+#				MULTI_VALUE LIST
+#				REQUIRED NAME LIST
+#				ARGN ${ARGN})
+#			message(STATUS "name: ${NAME}")
+#			message(STATUS "list: ${LIST}")
+#		endfunction()
+#
+#		test(NAME "hello" LIST a b c)
+#
+#		OUTPUT:
+#			name: hello
+#			list: a b c
+#
+include(CMakeParseArguments)
+function(px4_parse_function_args)
+
+	cmake_parse_arguments(IN "" "NAME" "OPTIONS;ONE_VALUE;MULTI_VALUE;REQUIRED;ARGN" "${ARGN}")
+	cmake_parse_arguments(OUT "${IN_OPTIONS}" "${IN_ONE_VALUE}" "${IN_MULTI_VALUE}" "${IN_ARGN}")
+
+	if (OUT_UNPARSED_ARGUMENTS)
+		#message(FATAL_ERROR "${IN_NAME}: unparsed ${OUT_UNPARSED_ARGUMENTS}")
+		# TODO: reenable
+	endif()
+
+	foreach(arg ${IN_REQUIRED})
+		if (NOT OUT_${arg})
+			if (NOT "${OUT_${arg}}" STREQUAL "0")
+				message(FATAL_ERROR "${IN_NAME} requires argument ${arg}\nARGN: ${IN_ARGN}")
+			endif()
+		endif()
+	endforeach()
+
+	foreach(arg ${IN_OPTIONS} ${IN_ONE_VALUE} ${IN_MULTI_VALUE})
+		set(${arg} ${OUT_${arg}} PARENT_SCOPE)
+	endforeach()
+
+endfunction()